home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 023 - Big U Macroworks.dsk / RAM.SETUP.bas < prev    next >
BASIC Source File  |  2019-02-16  |  4KB  |  52 lines
  1. 1  ONERR  GOTO 470
  2. 2 D$ =  CHR$(4):KP = 49152:KR = 49168:Q$ =  CHR$(34):CS =  -958:CL =  -868:BP$ =  CHR$(7)
  3. 3 LS = 16384: REM  START OF PROGRAM
  4. 10  TEXT : HOME : NORMAL : PRINT  CHR$(21)
  5. 20  PRINT "RAM.LOAD & RAM.SAVE"
  6. 30  PRINT "Setup Program        (See page 69)"
  7. 40  PRINT "-------------": PRINT 
  8. 50  PRINT "Copyright (c) 1985, Randy Brandt"
  9. 60  PRINT "Beagle Bros Micro Software, Inc."
  10. 70  VTAB 8: PRINT : CALL CS: PRINT "Set up which program?": PRINT : PRINT "L - RAM.LOAD": PRINT : PRINT "S - RAM.SAVE": PRINT : PRINT "Q - Quit"
  11. 75  PRINT : PRINT "Press "Q$"L"Q$", "Q$"S"Q$", or "Q$"Q"Q$": ";
  12. 80  GET X$: IF X$ = "Q"  OR X$ = "q"  THEN 550
  13. 90 RAM$ = "LOAD":LE = 466: IF X$ = "S"  OR X$ = "s"  THEN RAM$ = "SAVE":LE = 539: GOTO 120
  14. 100  IF X$ < >"L"  AND X$ < >"l"  THEN  PRINT BP$;: GOTO 80
  15. 120  VTAB 8: CALL CS: PRINT : PRINT "Loading RAM."RAM$
  16. 130  PRINT D$"BLOAD RAM."RAM$
  17. 140  GOSUB 450: REM    SLOT/DRIVE INFO
  18. 150  GET X$: IF X$ =  CHR$(27)  THEN 70
  19. 160  IF X$ = "U"  OR X$ = "u"  THEN SL = 6:DR = 1: GOTO 240
  20. 170  IF X$ < >"N"  AND X$ < >"n"  THEN  PRINT BP$;: GOTO 150
  21. 180  VTAB 17: PRINT : CALL CS
  22. 190  VTAB 18: PRINT "Enter new slot: ";: GET SL$:SL =  VAL(SL$): PRINT SL$: IF SL$ =  CHR$(27)  THEN 140
  23. 200  IF SL <4  OR SL >7  THEN  PRINT BP$;: GOTO 190
  24. 210  VTAB 18: HTAB 20: PRINT "Enter new drive: ";: GET DR$:DR =  VAL(DR$): PRINT DR$: IF DR$ =  CHR$(27)  THEN 190
  25. 220  IF DR <1  OR DR >2  THEN  PRINT BP$;: GOTO 210
  26. 230  VTAB 18: PRINT "Press Return to use slot "SL", drive "DR": ";: GET X$: IF X$ < > CHR$(13)  THEN 180
  27. 240 X = ((DR -1) *128) +SL *16: POKE LS +1,X
  28. 250  GOSUB 420
  29. 260  GET X$: IF X$ =  CHR$(27)  THEN 140
  30. 270  IF X$ = "U"  OR X$ = "u"  THEN NP = 0: GOTO 300
  31. 280  IF X$ < >"C"  AND X$ < >"c"  THEN  PRINT BP$;: GOTO 260
  32. 290 NP = 1: REM  YES, DO NOT PAUSE
  33. 300  VTAB 8: PRINT : CALL CS: PRINT "RAM."RAM$" setup:": PRINT : PRINT "Use slot "SL", drive "DR".": PRINT "Do ";: IF NP = 1  THEN  PRINT "not ";
  34. 310  PRINT "pause and prompt.": PRINT 
  35. 320  PRINT : PRINT "Press Return to save RAM."RA$",": PRINT "or press Escape to redo ";
  36. 330  GET X$: IF X$ =  CHR$(27)  THEN 140
  37. 335  IF X$ < > CHR$(13)  THEN 330
  38. 340  VTAB  PEEK(37): HTAB 1: PRINT "Saving configured version...";: CALL CS: PRINT 
  39. 350  POKE LS +11,3: IF NP = 1  THEN  POKE LS +11,0: REM  PAUSE SETTING
  40. 360  PRINT D$"UNLOCK RAM."RA$
  41. 361  PRINT D$"BSAVE RAM."RA$",A$4000,L"LE: GOTO 70
  42. 420  VTAB 8: PRINT : CALL CS: PRINT "The RAM.LOAD and RAM.SAVE programs": PRINT "normally pause and prompt you to": PRINT "insert the correct disk.": PRINT 
  43. 430  PRINT "It can be handy to skip this delay": PRINT "if the floppy is already in. See the": PRINT "manual for details.": PRINT 
  44. 440  PRINT "C - Cancel the pause": PRINT : PRINT "U - Use the pause": PRINT : PRINT "Press "Q$"C"Q$" or "Q$"U"Q$": ";: RETURN 
  45. 450  VTAB 8: PRINT : CALL CS: PRINT "RAM files are usually copied to and": PRINT "from the floppy in slot 6, drive 1.": PRINT 
  46. 460  PRINT "U - Use slot 6, drive 1": PRINT : PRINT "N - New slot and drive": PRINT : PRINT "Press "Q$"U"Q$" or "Q$"N"Q$": ";: RETURN 
  47. 470 ER =  PEEK(222):EL =  PEEK(218) + PEEK(219) *256
  48. 480  IF EL = 130  THEN  VTAB 9: PRINT BP$;"Can't find RAM.";RAM$" ": PRINT "Insert the correct disk and press a key ";: GET X$: ON X$ < > CHR$(27) GOTO 130: GOTO 550
  49. 485  IF EL = 360  THEN 361: REM  ON NEW DISK
  50. 490  IF EL = 361  THEN  VTAB 13: PRINT BP$: CALL CS: PRINT "DISK ERROR": PRINT "Press Return to try again": PRINT "or press Escape: ";: GET X$: ON X$ < > CHR$(27) GOTO 360: GOTO 140
  51. 510  POKE 216,0: RESUME 
  52. 550  HOME : PRINT : PRINT "TYPE "Q$"RUN"Q$" TO RESTART."